'' 完毕：
Imports System.IO
Imports System.Drawing
Imports System.Collections.Generic
Imports GrapeCity.Documents.Drawing
Imports GrapeCity.Documents.Pdf
Imports GrapeCity.Documents.Text
Imports GCTEXT = GrapeCity.Documents.Text
Imports GCDRAW = GrapeCity.Documents.Drawing

'' 此示例使用柱状布局呈现阿拉伯文本。
'' 另请参阅MultiLang 和JapaneseColumns。
Public Class ArabicText
    Const text = "العربية أكبر لغات المجموعة السامية من حيث عدد المتحدثين، وإحدى أكثر اللغات انتشارًا في العالم، يتحدثها أكثر من 422 مليون نسمة،1 ويتوزع متحدثوها في المنطقة المعروفة باسم الوطن العربي، بالإضافة إلى العديد من المناطق الأخرى المجاورة كالأحواز وتركيا وتشاد ومالي والسنغالوارتيرياوللغة العربية أهمية قصوى لدى أتباع الديانة الإسلامية، فهي لغة مصدري التشريع الأساسيين في الإسلام: القرآن، والأحاديث النبوية المروية عن النبي محمد، ولا تتم الصلاة في الإسلام (وعبادات أخرى) إلا بإتقان بعض من كلمات هذه اللغة. والعربية هي أيضًا لغة طقسية رئيسية لدى عدد من الكنائس المسيحية في العالم العربي، كما كتبت بها الكثير من أهم الأعمال الدينية والفكرية اليهودية في العصور الوسطى. وأثّر انتشار الإسلام، وتأسيسه دولًا، أرتفعت مكانة اللغة العربية، وأصبحت لغة السياسة والعلم والأدب لقرون طويلة في الأراضي التي حكمها المسلمون، وأثرت العربية، تأثيرًا مباشرًا أو غير مباشر على كثير من اللغات الأخرى في العالم الإسلامي، كالتركية والفارسية والأرديةوالالبانية واللغات الأفريقية الاخرى واللغات الأوروبية مثل الروسية والإنجليزية والفرنسية والأسبانية والايطالية والألمانية.كما انها تدرس بشكل رسمى او غير رسمى في الدول الاسلامية والدول الأفريقية المحادية للوطن العربى."

    Function CreatePDF(ByVal stream As Stream) As Integer

        Using reds As GCDRAW.Image = GCDRAW.Image.FromFile(Path.Combine("Resources", "Images", "reds.jpg")),
            firth As GCDRAW.Image = GCDRAW.Image.FromFile(Path.Combine("Resources", "Images", "firth.jpg")),
            purples As GCDRAW.Image = GCDRAW.Image.FromFile(Path.Combine("Resources", "Images", "purples.jpg"))
            Dim times = GCTEXT.Font.FromFile(Path.Combine("Resources", "Fonts", "times.ttf"))
            Dim ia = New ImageAlign(ImageAlignHorz.Left, ImageAlignVert.Top, True, True, True, False, False)

            Dim doc = New GcPdfDocument()

            '' 将保存并呈现文本的 TextLayout：
            Dim tl = New TextLayout(72) With {
                .FirstLineIndent = 18,
                .ParagraphSpacing = 6,
                .TextAlignment = TextAlignment.Justified,
                .RightToLeft = True
            }
            Dim tf = New TextFormat() With {.Font = times, .FontSize = 12}
            '' 重复测试文本以填充几页：
            For i = 1 To 12
                tl.Append(text, tf)
                tl.AppendLine()
            Next

            '' 将文本布局为 3 列：
            '' (此示例中的逻辑/代码与JapaneseColumns相同
            Const NCOLS = 3
            Dim margin = 36.0F
            Dim gap = 18.0F
            Dim page = doc.NewPage()
            page.Landscape = True
            Dim colWid = (page.Size.Width - margin * 2 - gap * (NCOLS - 1)) / NCOLS
            tl.MaxWidth = page.Size.Width
            tl.MaxHeight = page.Size.Height
            tl.MarginTop = margin
            tl.MarginBottom = margin
            tl.MarginRight = margin
            tl.MarginLeft = margin + (colWid + gap) * (NCOLS - 1)
            '' 我们可以指定任意矩形，让文本围绕其流动。
            '' 在本例中，我们添加 3 个区域来绘制一些图像：
            tl.ObjectRects = New List(Of ObjectRect)() From {
                New ObjectRect(page.Size.Width - margin - 240, margin, 240, 240),
                New ObjectRect(margin + 100, margin + 60, 133, 100),
                New ObjectRect(margin, page.Size.Height - margin - 300, 300, 300)
            }
            '' 将对象矩形转换为图像区域，调整以提供美观的填充：
            Dim rReds = tl.ObjectRects(0).ToRectangleF()
            rReds.Inflate(-4, -3)
            Dim rFirth = tl.ObjectRects(1).ToRectangleF()
            rFirth.Inflate(-4, -3)
            Dim rPurples = tl.ObjectRects(2).ToRectangleF()
            rPurples.Inflate(-4, -3)
            page.Graphics.DrawImage(reds, rReds, Nothing, ia)
            page.Graphics.DrawImage(firth, rFirth, Nothing, ia)
            page.Graphics.DrawImage(purples, rPurples, Nothing, ia)

            '' 调用：它计算绘制文本所需的字形，并将其布局：
            tl.PerformLayout(True)

            Dim done = False
            '' 当仍有文本要渲染时循环：
            While Not done
                For col = 1 To NCOLS

                    Dim nextcol = If(col < NCOLS, col, 0)
                    '' TextSplitOptions 告诉 TextLayout.Split() 如何布局剩余的文本。
                    '' 在本例中，我们通过更新顶部和底部边距从一列前进到另一列：
                    Dim tso = New TextSplitOptions(tl) With {
                        .RestMarginRight = margin + (colWid + gap) * nextcol,
                        .RestMarginLeft = margin + (colWid + gap) * (NCOLS - 1 - nextcol)
                    }
                    Dim rest As TextLayout = Nothing
                    Dim split = tl.Split(tso, rest)
                    page.Graphics.DrawTextLayout(tl, PointF.Empty)
                    If split <> SplitResult.Split Then
                        done = True
                        Exit For
                    End If
                    tl = rest
                Next
                If Not done Then
                    page = doc.NewPage()
                    page.Landscape = True
                    '' 我们只想在第一页上渲染图像，所以清除ObjectRects：
                    If Not tl.ObjectRects Is Nothing Then
                        tl.ObjectRects = Nothing
                        '' 我们需要重做布局，但不需要重新计算字形：
                        tl.PerformLayout(False)
                    End If
                End If
            End While
            ''
            '' 完毕：
            doc.Save(stream)
            Return doc.Pages.Count
        End Using
    End Function
End Class