'' 完毕：
Imports System
Imports System.IO
Imports System.Drawing
Imports System.Numerics
Imports GrapeCity.Documents.Pdf
Imports GrapeCity.Documents.Text
Imports GCTEXT = GrapeCity.Documents.Text
Imports GCDRAW = GrapeCity.Documents.Drawing

'' 此示例展示了如何添加简单的类似文本水印的叠加层
'' 到现有 PDF 的所有页面。
Public Class AddWatermark
    Function CreatePDF(ByVal stream As Stream) As Integer
        Dim doc = New GcPdfDocument()
        Using fs = File.OpenRead(Path.Combine("Resources", "PDFs", "SlidePages.pdf"))
            doc.Load(fs)
            For Each page In doc.Pages
                Dim g = page.Graphics

                '' 用于绘制“水印”的文本布局：
                Dim tl = g.CreateTextLayout()
                tl.Append("DsPdf Demo")
                tl.DefaultFormat.Font = GCTEXT.Font.FromFile(Path.Combine("Resources", "Fonts", "calibrib.ttf"))
                tl.DefaultFormat.FontSize = g.Resolution
                '' 半透明颜色：
                tl.DefaultFormat.ForeColor = Color.FromArgb(128, Color.Yellow)
                tl.DefaultFormat.GlyphAdvanceFactor = 1.5F
                tl.PerformLayout()

                '' 旋转角度（弧度）- 从页面的左/下角到右/上角：
                Dim angle = -Math.Asin(g.CanvasSize.Width / g.CanvasSize.Height)
                '' 页面中心：
                Dim center = New PointF(g.CanvasSize.Width / 2, g.CanvasSize.Height / 2)
                '' 文本大小的额外偏移：
                Dim delta = New PointF(
                    ((tl.ContentWidth * Math.Cos(angle) - tl.ContentHeight * Math.Sin(angle)) / 2),
                    ((tl.ContentWidth * Math.Sin(angle) + tl.ContentHeight * Math.Cos(angle)) / 2))

                '' 在页面中心对角绘制水印文本
                '' （矩阵变换从最后到第一个应用）：
                g.Transform =
                    Matrix3x2.CreateRotation(angle) *
                    Matrix3x2.CreateTranslation(center.X - delta.X, center.Y - delta.Y)
                g.DrawTextLayout(tl, PointF.Empty)
                g.Transform = Matrix3x2.Identity
            Next
            doc.Save(stream)
        End Using
        Return doc.Pages.Count
    End Function
End Class